Stockez les images statiques de vos formulaires et états Access hors de la base de données

C'est, en principe, ici que l'on spécifierait le chemin d'une image. Plusieurs types de fichiers sont autorisés, dépendant des filtres d'importation dont vous disposez. Toutefois, les boutons de commande ou de bascule ne peuvent comporter que des images bitmap.

Dans notre cas, nous n'affecterons aucune valeur à cette propriété lors de la construction de l'état ou du formulaire. « (aucune) » apparaîtra en regard de la propriété.

Ici, lorsqu'une image a été affectée à la propriété précédente on a le choix entre « Intégré » et « Attaché ».

Si l'on choisit « Intégré », l'image est incorporée dans l'objet et fait partie du fichier de base de données. La taille de la base de données s'accroît alors d'autant d'octets que le fichier image (parfois plus).

Lorsque cette propriété est définie sur « Attaché », la taille de la base de données n'augmente pas, car Access enregistre seulement un pointeur vers l'emplacement.

Lors de la construction de l'état ou du formulaire, nous fixerons la valeur de cette propriété à « Attaché ».

Voici une propriété rarement utilisée et pourtant bien pratique ! C'est un pense-bête, vous pouvez y inscrire ce que vous voulez avec un maximum de 2048 caractères. Contrairement aux autres propriétés, le paramétrage de celle-ci n'affecte pas les attributs d'un objet.

Nous allons nous en servir pour y stocker le nom du fichier image que nous voudrons affecter à ce contrôle en temps utile.

On pourrait y inscrire le chemin complet. Toutefois, nous avons opté pour le rassemblement de toutes les images de notre base de données dans un même répertoire que nous logerons dans le même dossier que la base.

Cette méthode a deux avantages :

• si on connaît le nom du fichier de l'image, on peut construire de chemin avec l'instruction :

CurrentProject.Path & "\Images\" & "le contenu de la propriété Remarque"

• quel que soit le dossier où se situent la base et le répertoire : sur votre PC, une clé USB...

Ceci a pour but d'éviter d'inclure un code semblable pour chaque objet. Ce qui facilite la portabilité (puisque plus générique) et la maintenance éventuelle.

Le code de la procédure sera donc logé dans un module.

L'objet y fera appel dans son événement Sur ouverture :

Private Sub Form_Open(Cancel As Integer)
Call AmnImages
End Sub

Lorsqu'elle se déclenchera, cette procédure doit être capable de déterminer quel est l'objet qui l'appelle. C'est en effet ce formulaire ou cet état spécifique qu'il faut toiletter.

Access dispose de la propriété CodeContextObject pour répondre à ce besoin. Elle permet de déterminer dans quel objet du code Visual Basic est en cours d'exécution.

Quand la routine AmnImages() s'exécute : CodeContextObject représente l'objet qui a déclenché l'exécution. Il hérite alors de toutes les propriétés de ce dernier.

Par exemple, si le formulaire fImagesExternes appelle AmnImages(), nous aurons :

CodeContextObject.name égal à « fImagesExternes » ;
CodeContextObject.Controls représentera la collection des contrôles de fImagesExternes ;
CodeContextObject.picture donnera le chemin de l'image de fond.

Il faut d'abord déclarer les variables et donner l'étiquette où l'on gère les erreurs :

Dim Ctrl As Control         ' pour boucler dans la collection des contrôles
Dim bFond As Boolean    ' nous permettra de savoir si l'on s'occupe ou non de l'image de fond 
On Error GoTo GestionErreur

On s'occupe ensuite de l'image de fond de l'objet.

On positionne le flag bFond à True.

Comme il s'agit d'atteindre des propriétés de l'objet (et non d'un contrôle), on utilise les propriétés de CodeContextObject.

bFond = True
If IsNull(CodeContextObject.PictureData) And CodeContextObject.PictureType = 1 And CodeContextObject.Tag Like "*.*" Then
      CodeContextObject.Picture = CurrentProject.Path & "\Images\" & CodeContextObject.Tag
End If

Si les trois conditions sont remplies (Image = (aucune) ; Type image = Attaché ; Remarque = la structure d'un nom de fichier), on construit le chemin complet de l'image et on l'affecte à la propriété Image de l'objet.

Deux causes d'erreur : le format de l'image est inadéquat (2214) ou l'image est introuvable (2220). Nous expliquerons plus loin comme réagir.

Ensuite, on positionne le flag bFond à False : on va parcourir la collection de contrôles de l'objet :

ImgControles:            'cette étiquette sera nécessaire pour le traitement des erreurs
bFond = False
For Each Ctrl In CodeContextObject.Controls
     [...]
  Next Ctrl

et pour chaque contrôle, si les trois propriétés ont la valeur ad hoc, on affecte le chemin de l'image :

     If Ctrl.Picture = "(aucune)" And Ctrl.PictureType = 1 And Ctrl.Tag Like "*.*" Then
      Ctrl.Picture = CurrentProject.Path & "\Images\" & Ctrl.Tag
     End If

Trois erreurs sont possibles : le contrôle examiné n'a pas ce type de propriété (438) ; le format de l'image est inadéquat (2214) ou l'image est introuvable (2220).

On passe en revue les cas possibles :

Select Case err.Number
       [...]
End Select

438 : le contrôle actuellement examiné n'a pas l'une des propriétés qui nous intéressent.

Rien de spécial, on passe au suivant :

       Case 438  
          Resume Next

2114 : le format de l'image est inadéquat. Il faut distinguer si cette erreur survient

• soit lors du traitement de l'image de fond : il faut alors prévenir l'utilisateur et continuer avec le processus relatif aux contrôles. Il n'y aura pas d'image de fond ;

       Case 2114 
          If bFond = True Then         
             MsgBox "(2114) L'image de fond de '" & CodeContextObject.Name & "', c'est-à-dire : '" _
                  & CodeContextObject.Tag & "' est d'un format invalide."
             Resume ImgControles

• soit lors du traitement de l'image d'un contrôle : il faut alors prévenir l'utilisateur, affecter une image par défaut et passer au contrôle suivant :

             MsgBox "(2114) L'image '" & Ctrl.Tag & "' est d'un format invalide pour le contrôle '" _
                  & Ctrl.Name & "' de l'objet '" & CodeContextObject.Name & "'."
             Ctrl.Picture = CurrentProject.Path & "\Images\Default.bmp"
             Resume Next

2220 : l'image est absente. C'est exactement la même réaction que celle de l'erreur 2214, aux messages d'erreurs près.

       Case 2220 
          If bFond = True Then         'C'est l'image de fond
             MsgBox "(2220) L'image de fond de '" & CodeContextObject.Name & "', c'est-à-dire : '" _
                  & CodeContextObject.Tag & "' est absente."
             Resume ImgControles
          Else
             MsgBox "(2220) L'image '" & Ctrl.Tag & "' est absente pour le contrôle '" _
                & Ctrl.Name & "' de l'objet '" & CodeContextObject.Name & "'."
             Ctrl.Picture = CurrentProject.Path & "\Images\Default.bmp"
             Resume Next
          End If

Enfin, on peut utiliser ceci pour les erreurs non prévues :

       Case Else
          MsgBox "Erreur inattendue dans AmnImages" & vbLf _
               & err.Number & " : " & err.Description, vbCritical